AYUDA EN LÍNEA
 WINDEVWEBDEV Y WINDEV MOBILE

Este contenido se ha traducido automáticamente.  Haga clic aquí  para ver la versión en inglés.
Ayuda / WLanguage / Administrar bases de datos / Big Data / Gestión de bases de datos HBase
  • Presentación
  • ¿Cómo se organiza una base de datos HBase?
  • ¿Cómo manipular una base de datos HBase en programación?
  • ¿Cómo crear un HBase tabla?
  • ¿Cómo recuperar la lista de tablas que se encuentran en una base de datos HBase?
  • ¿Cómo recuperar la description de una base de datos HBase?
  • ¿Cómo eliminar un HBase tabla?
  • ¿Cómo leer los datos que se encuentran en una base de datos HBase?
  • ¿Cómo escribir datos en una base de datos HBase?
  • ¿Cómo eliminar datos de un HBase tabla?
  • ¿Cómo realizar una navegación con filtro en un HBase tabla?
WINDEV
WindowsLinuxUniversal Windows 10 AppJavaReportes y ConsultasCódigo de Usuario (UMC)
WEBDEV
WindowsLinuxPHPWEBDEV - Código Navegador
WINDEV Mobile
AndroidWidget Android iPhone/iPadIOS WidgetApple WatchMac CatalystUniversal Windows 10 App
Otros
Procedimientos almacenados
Gestión de bases de datos HBase
Presentación
HBase es una base de datos distribuida no relacional (NoSQL), basada en columnas y que utiliza un almacenamiento no estructurado para las tablas grandes.
HBase es un componente central de Hadoop.
HBase ha sido concebido para procesar grandes volúmenes de datos (varios millones de filas, varios millones de columnas por fila) y datos no estándar (cada fila puede tener una estructura diferente a la del siguiente fila).
¿Cómo se organiza una base de datos HBase?
En una base de datos HBase, los datos se almacenan en tablas (archivos), de forma desnormalizada.
Cada tabla se divide en familias de columnas (ítems), que a su vez contienen columnas.
Cada fila (equivalente a un Record en un DBMS tradicional) se identifica con una única "rowKey".
Para cada fila, en la misma familia de columnas, el número y el nombre de las columnas son libres.
"rowKey" es la única clave de la tabla.
Una celda es la intersección entre un fila y una columna.
Se almacena el historial del contenido de la celda, así como su hora (fecha/hora en que se escribió)..
Tiene la capacidad de implementar filtros en una HBase tabla (un poco como un filtro en HFSQL).
¿Cómo manipular una base de datos HBase en programación?
WLanguage te lo permite:
Atención: Las funciones de HBase están disponibles en tiempo de edición y ejecución desde Windows Vista o Windows Server 2008.

¿Cómo crear un HBase tabla?

Para crear una HBase tabla, usted debe:
  1. Definir e inicializar una hbConnection Variable.
  2. Definir e inicializar una hbTableDescription Variable. Este Variable contiene un array de hbColumnDescription Variable s que describen las columnas.
  3. Utilice la función hbCreateTable.Ejemplo:
// Connection
Connection is hbConnection
Connection.Server = "MyServer"
// Describe the table
TableDesc is hbTableDescription
TableDesc.Name = "blog"
// Describe the "Post" column
ColDesc is hbColumnDescription
ColDesc.Name = "Post"
Add(TableDesc.Column, ColDesc)
// Create the table
hbCreateTable(Connection, TableDesc)

¿Cómo recuperar la lista de tablas que se encuentran en una base de datos HBase?

Para recuperar la lista de tablas encontradas en una base de datos de HBase, debe:
  1. Definir e inicializar una hbConnection Variable.
  2. Utilice la función hbListTable.Ejemplo:
// Connection
Connection is hbConnection
Connection.Server = "MyServer"
// Display the list of tables
Trace(hbListTable(Connection))

¿Cómo recuperar la description de una base de datos HBase?

Para recuperar la description de una base de datos HBase, debe:
  1. Definir e inicializar una hbConnection Variable.
  2. Utilice la función hbGetTableDescription.
  3. Recuperar el tabla description en un hbTableDescription Variable. Este Variable contiene un array de hbColumnDescription Variable s que describen las columnas.Ejemplo:
// Connection
Connection is hbConnection
Connection.Server = "MyServer"
// Retrieve the description of the table
TableDesc is hbTableDescription = hbGetTableDescription(Connection, "blog")
// Display the name of the table
Trace("table: " + TableDesc.Name)
// Display the description of columns
FOR EACH ColDesc OF TableDesc.Column
Trace(TAB + "column: " + ColDesc.Name)
Trace(TAB + TAB + "attribute: ")
FOR EACH AttributeVal, AttributeName of ColDesc.Attribute
Trace(TAB + TAB + AttributeName + " = " + AttributeVal)
END
END

¿Cómo eliminar un HBase tabla?

Para borrar una HBase tabla, debe:
  1. Definir e inicializar una hbConnection Variable.
  2. Utilice hbDeleteTable y especifique el nombre de la tabla a eliminar.Ejemplo:
// Connection
Connection is hbConnection
Connection.Server = "MyServer"
// Delete the table
hbDeleteTable(Connection, "blog")

¿Cómo leer los datos que se encuentran en una base de datos HBase?

Para leer los datos encontrados en una base de datos de HBase, debe:
  1. Definir e inicializar una hbConnection Variable.
  2. Definir e inicializar una hbReading Variable. Este Variable contiene un array de hbColumn Variable s que describe las columnas a recuperar.
  3. Utilice la función hbLeer.
  4. Leer los datos en el resultado de hbCellEjemplo:
// Connection
Connection is hbConnection
Connection.Server = "MyServer"
// Description of data to read
Reading is hbReading
Reading.Row = "post1"
Reading.Version = 2
// Column description
Col is hbColumn
Col.Family = "Post"
Add(Reading.Column, Col)
// Read data
MyResult is array of hbCells = hbRead(Connection, "blog", Reading)
// Display the data read
FOR EACH Cell OF MyResult DO
Trace("Column: " + Cell.Column.Qualifier + "; Value: " + ...
Cell.Value + "; timestamp: " + Cell.Timestamp)
END

¿Cómo escribir datos en una base de datos HBase?

Para escribir datos en una base de datos de HBase, debe:
  1. Definir e inicializar una hbConnection Variable.
  2. Definir e inicializar una hbWriting Variable. Este Variable contiene un array de hbCell Variable s que describen los datos a escribir.
  3. Utilice la función hbWrite.Ejemplo:
// Connection
Connection is hbConnection
Connection.Server = "MyServer"
// Description of data to write
Writing is hbWriting
Writing.Row = "post1"
Cell is hbCell
Cell.Column.Family = "post"
Cell.Column.Qualifier = "title"
Cell.Value = "This is my blog post."
Add(Writing.Cell, Cell)
// Write data
hbWrite(Connection, "blog", Writing)

¿Cómo eliminar datos de un HBase tabla?

Para borrar datos de una HBase tabla, debe:
  1. Definir e inicializar una hbConnection Variable.
  2. Utilice hbDelete y especifique el identificador de la fila a eliminar.Ejemplo:
// Connection
Connection is hbConnection
Connection.Server = "MyServer"
// Delete the entire row
hbDelete(Connection, "blog", "post1")

¿Cómo realizar una navegación con filtro en un HBase tabla?

Para realizar una búsqueda con filtro en una base de datos de HBase, debe:
  1. Definir e inicializar una hbConnection Variable.
  2. Definir e inicializar una hbScanParameter Variable. Este Variable define el filtro a implementar.
  3. Examinar los datos filtrados (correspondientes a la hbScanParameter Variable) mediante la sentencia FOR EACH. El resultado de la búsqueda se lee en un hbScanResult Variable. Ejemplo:
// Connection
Connection is hbConnection
Connection.Server = "MyServer"
// Filter description
MyScan is hbScanParameter
MyScan.Connection = Connection
MyScan.Table = "blog"
// Filters, for all the rows, the values of columns whose name starts with "Title"
MyScan.Filter = "{ ""type"": ""ColumnPrefixFilter"", ""value"": """ + ...
Encode("Title", encodeBASE64) + """ }"
// Loops through and displays the filtered data
// MyResult is an hbScanResult variable
FOR EACH MyResult OF MyScan
Trace("The column " + MyResult.Column.Family + ":" + ...
MyResult.Column.Qualifier + ...
" of the row " + MyResult.Row + " is set to " + MyResult.Value)
END
Ver también
Versión mínima requerida
  • Versión 21
Esta página también está disponible para…
Comentarios
Haga clic en [Agregar] para publicar un comentario

Última modificación: 27/05/2022

Señalar un error o enviar una sugerencia | Ayuda local