Array (tipo Variable)

AYUDA EN LÍNEA
WINDEV, WEBDEV Y WINDEV MOBILE

Versión:

Inicio | Iniciar sesión | Español

Este contenido se ha traducido automáticamente. Haga clic aquí para ver la versión en inglés.

Ayuda / WLanguage / Sintaxis WLanguage / Declaración de variables

Otros tipos de arrays
Procedure: Declaración de un parámetro array
Pasar una array como parámetro a una Procedure
Funciones WLanguage y arrays
Array de arrays, asociativo array, cola, pila, lista
Limitaciones: Elementos de una array
Matrices en las clases
Agregar el contenido de una estructura a un array de estructuras sin utilizar una variable de la estructura

WINDEV

WEBDEV

WINDEV Mobile

Otros

Ver también

Array (tipo Variable)

Un array es un tipo estructurado que permite agrupar una serie de elementos del mismo tipo. Puede acceder a cada elemento del array por su índice.

Ejemplo

// Declares an array initialized with the names of days of the week
DayArray is array of strings = ["Monday", "Tuesday", "Wednesday", "Thursday", "Friday"]
// Handles the array
DayArray[2] // Returns "Tuesday"

// Declares an array of integers
ValueArray is array of int
// Populates the array of integers by adding values
Add(ValueArray, 5)
Add(ValueArray, 10)
Add(ValueArray, 15)
// Browses the array values
FOR EACH x OF ValueArray
	// x is successively equal to 5, 10, 15
	...
END

// Declares an array of integers
ValueArray is array <growth=1> of int
// Enlarges the array to insert the value 1: 10
ValueArray[1] = 10
// Enlarges the array to insert the value 2: 20
ValueArray[2] = 20
// Enlarges the array to insert the value 3: 30
ValueArray[3] = 30
// Browses the array values
FOR EACH x OF ValueArray
	// x is successively equal to 10, 20, 30
END

// Declares an array of integers
ValueArray is array <growth=N> of int
// Enlarges the array to insert the value 1: 10
ValueArray[1] = 10
// Enlarges the array to insert the value 5: 50
// The values 2, 3 and 4 are initialized to 0
ValueArray[5] = 50
// Browses the array values
FOR EACH x OF ValueArray
	// x is successively equal to 10, 0, 0, 0, 50
END

// Declare an Array of arrays
arrMyArray is array of strings
nArrIndex is int

nArrIndex = Add(arrMyArray)
Add(arrMyArray[nArrIndex], "January")
Add(arrMyArray[nArrIndex], "300")
nArrIndex = Add(arrMyArray)
Add(arrMyArray[nArrIndex], "February")
Add(arrMyArray[nArrIndex], "600")

Trace(arrMyArray[1,1]) // Displays "January"
Trace(arrMyArray[1,2]) // Displays "300"

Sintaxis

Declaración de una array unidimensional (sintaxis 1)

<Array name> is array [<growth>] [ [<Dimension 1>] ] <Type of array elements>

Ejemplo:

arrString is array <growth=N> [10] strings
arrInt is array [5] ints

Declaración de una array unidimensional (sintaxis 2) Ocultar los detalles

<Array name> is array [<growth>] of [<Dimension>] <Type of array elements>

<Array name>:

Nombre de la array Variable a declarar.

<growth>:

Modo opcional para ampliar el array:
ningún valor (predeterminado) o "<growth=0>": la array no se amplía automáticamente. Por ejemplo, se producirá un error de ejecución si array contiene 5 elementos y si el programa accede al elemento 6 o 100.
"<growth>" o "<growth=1>": la array se amplía automáticamente en 1 elemento. Por ejemplo, si el array contiene 5 elementos y el programa accede al elemento 6, el array se amplía automáticamente a manipular el elemento 6 ; si el programa accede al elemento 100 se producirá un error de ejecución.
"<ampliar=N>": la array se amplía automáticamente con el número de elementos necesarios. Por ejemplo, si el array contiene 5 elementos y si el programa accede al elemento 6, el array se amplía automáticamente a manipular el elemento 6 ; si el programa accede al elemento 100, el array se amplía automáticamente a manipular el elemento 100.. Los elementos intermedios se inicializan con el valor Default para este tipo de elementos array.
Esta función no es compatible.
Observación: Para ampliar una array con varias dimensiones, utilice Dimensión.

<Dimension>:

Dimensión opcional de la array. Este parámetro puede:
ser indeterminado o corresponder a *o 0: la array se inicializa vacía.
corresponden a un valor constante o a un entero Variable: la array se inicializa con el número especificado de elementos. Cada elemento se inicializa con el valor Default de su tipo.

<Type of array elements>:

Tipo de los elementos del array. Consulte Los diferentes tipos de WLanguage.
Observación: Los elementos que componen la array también pueden ser arrays, arrays fijo, arrays asociativo, colas, pilas o listas..

Declaración de una array multidimensional (10 dimensiones como máximo) - Sintaxis 1

<Array name> is array of [ [<Dimension 1> [, <Dimension 2>]...[, <Dimension 10>]] ] <Type of array elements>

Ejemplo:

arrString is array [10,20] strings
arrInt is array [3,5,2] ints

Declaración de una array multidimensional (10 dimensiones como máximo) - Sintaxis 2 Ocultar los detalles

<Array name> is array of [<Dimension 1> [by <Dimension 2>] ... [by <Dimension 10>]] <Type of array elements>
OR
<Array name> is array of [<Dimension 1> [, <Dimension 2>]... [, <Dimension 10>]] <Type of array elements>

<Array name>:

Nombre de la array Variable a declarar.

<Dimension 1>...<Dimension 10>:

Dimensión 1 a 10 de la array. El valor de la dimensión puede corresponder a:
* o 0: la dimensión se inicializa con el elemento 0.
un valor constante o un entero Variable: la dimensión se inicializa con el número especificado de elementos. Cada elemento se inicializa con el valor Default de su tipo.

<Type of array elements>:

Tipo de los elementos del array. Consulte Los diferentes tipos de WLanguage.
Observación: Los elementos que componen la array también pueden ser arrays, arrays fijo, arrays asociativo, colas, pilas o listas..

Declaración de un parámetro array Ocultar los detalles

One-dimensional array:
<Parameter name> is array of [<Dimension>] <Type of array elements>

Two-dimensional array
<Parameter name> is array of <Dimension 1> by <Dimension 2> <Type of array elements>

N-dimensional array
<Parameter name> is array of [<Dimension 1> [by <Dimension 2>] ... [ by <Dimension N>]] <Type of array elements>

<Parameter name>:

Nombre del parámetro array a declarar.

<Dimension n>:

puede no especificarse, puede corresponder a * , 0 o a un valor constante.

<Type of array elements>:

Tipo de los elementos del array. Consulte Los diferentes tipos de WLanguage.
Observación: Los elementos que componen la array también pueden ser arrays, arrays fijo, arrays asociativo, colas, pilas o listas..

Refiriéndose a un array Ocultar los detalles

Referring to an element in a one-dimensional array:
<Array name>[Index1]

Referencing an element in a two-dimensional array:
<Array name>[Index1, Index2]
OR
<Array name>[index1][index2]

Referring to an element in a n-dimensional array:
<Array name>[Index1,...,IndexN]
OR
<Array name>[Index1]...[IndexN]

<Array name>:

Nombre de la array a utilizar.

<Index1>:

Índice del elemento para la 1.ª dimensión.

<Index2>:

Índice del elemento para la 2.ª dimensión.

<IndexN>:

Índice del elemento para la N-ésima dimensión (N <= 10).

Observaciones

Otros tipos de arrays

La palabra clave Array permite definir un array. Existen otros tipos de arrays "avanzada":

Dynamic array: Array asignada a petición.
array fija: array de tamaño fijo (recomendado para las APIs de Windows).
Asociación array: Array permite almacenar elementos indexados sobre cualquier tipo de información.

Procedure: Declaración de un parámetro array

Un array puede ser pasado como parámetro a un Procedure. Por ejemplo:

// Adds a customer into the array
PROCEDURE AddCustomer(arrCustomer is array of * CCustomer,
	sName is string,
	sInfo is string)
// Builds the new customer object
c is CCustomer(sName, sInfo)
// Adds the object into the array
Add(arrCustomer, c)

Observaciones:

El tipo de los elementos que se encuentran en la array pasada como parámetro debe ser el mismo que el de la declaración.
El número de dimensiones de la array pasada como parámetro debe ser el mismo que el de la declaración.
El número de elementos encontrados en cada dimensión de la array pasada como parámetro debe corresponder a la declaración:
- si el número de elementos para la dimensión es *, no se realiza ninguna verificación.
- si se especifica el número de elementos para la dimensión, el número de elementos debe ser idéntico.
No se realiza ninguna verificación durante la compilación: Los controles se realizan en tiempo de ejecución.

Pasar una array como parámetro a una Procedure

Un array puede ser pasado como parámetro a un Procedure. Para ello, utilice la siguiente sintaxis:

<Procedure name>(<Array name>)

Por ejemplo:

SuppArray is array of 10 by 50 strings
// Call to the DisplayArray procedure
DisplayArray(SuppArray)

Funciones WLanguage y arrays

Se pueden utilizar varias funciones de WLanguage para manipular el arrays. Tiene la capacidad de realizar clasificaciones, búsquedas, etc.. Para obtener más información, consulte Funciones de arrays.

Array de arrays, asociativo array, cola, pila, lista

Se soportan las siguientes sintaxis:

<variable> is array of arrays of int
<variable> is array of arrays of 5 int
<variable> is array of 5 arrays of int
<variable> is array of 5 arrays of 5 int

<variable> is array of fixed arrays of 5 int
<variable> is array of 5 fixed arrays of 5 int

<variable> is array of associative arrays of int
<variable> is array of associative arrays (withDuplicates) of int
<variable> is array of associative arrays (withDuplicates,wlInt) of int
<variable> is array of 5 associative arrays of int
<variable> is array of 5 associative arrays (withDuplicates) of int
<variable> is array of 5 associative arrays (withDuplicates,wlInt) of int

<variable> is array of queues of int
<variable> is array of 5 queues of int

<variable> is array of stacks of int
<variable> is array of 5 stacks of int

<variable> is array of lists of int
<variable> is array of 5 lists of int

Limitaciones: Elementos de una array

Un array puede ser hecho de clases sólo si estas clases tienen un constructor sin parámetro (o con parámetros opcionales).
Un array no puede estar hecho de variables compuestas.
Y array no se puede hacer de arrays.
No es posible crear arrays de clases o estructuras.

Matrices en las clases

Cuando se copian instancias de clases, todos los miembros de la clase se copian en la nueva instancia excepto arrays. Por lo tanto, si se modifica el valor de un miembro de array, este valor se modifica en todas las instancias.

A get independiente arrays en todas las instancias de las clases, un array local debe ser declarado de la siguiente manera:

SystemClass is Class
	aDefaultArray is local array of 1 int
END

Agregar el contenido de una estructura a un array de estructuras sin utilizar una variable de la estructura

Si utiliza un array de estructuras con pocos miembros, puede ser más fácil agregar directamente una estructura utilizando el operador [ ] (corchetes).
Por ejemplo, para la siguiente estructura:

// Structure to store a letter and its ASCII code
STKey is Structure
sKey is string
nAsciiCode is int
END
// Array of structures
arrKeys is array of STKey

En la mayoría de los casos, el contenido se agrega utilizando una variable de un tipo declarado en la estructura:

// Temporary structure for the addition
stAKey is STKey
// Stores the letter A
stAKey.sKey = "A"
stAKey.nAsciiCode = Asc("A")
arrKeys.Add(stAKey)

Con el operador [ ], se obtiene una mejor legibilidad:

// Stores the letter A
arrKeys.Add(["A", Asc("A")])

Ver también

Versión mínima requerida

Versión 9

Esta página también está disponible para…

Comentarios

Exemplo OOP com Array

Class_Oop_Crud is Class

m_painelcontrole is array of st_painelcontrole

END

st_painelcontrole is Structure

gs_NomeJanela is string

end

/////////////-------------------- Open Window:
obj1 is Class_Oop_Crud //criou o objeto // carimbo

ArrayAdd(obj1:m_painelcontrole) //dar a dimensao 1 para o array

obj1.m_painelcontrole[1].gs_NomeJanela = MyWindow..Name

/////////////--------------------Button
Info(obj1.m_painelcontrole[1].gs_NomeJanela)

Boller

17 04 2024

ARRAY MULTIDIMENSIONAL VARIAVEL

arrayAntes is array of 1 by 4 STRING
ArrayDeleteAll(arrayAntes)
Dimension(arrayAntes,1,4)
X is int = 1
FOR EACH t000_frutas
arrayAntes[X,1]=t000_frutas.t000_frutas_ID
arrayAntes[X,2]=t000_frutas.t000_fruta
arrayAntes[X,3]=t000_frutas.t000_ordem
arrayAntes[X,4]=t000_frutas.t000_status
X++
Dimension(arrayAntes, X, 4)
END

BOLLER

28 02 2024

Novo exemplo de array multi dimensional

ATENÇÃO

arrayAntes is array of 1 by 4 STRING
arrayAntes .Add([dimensão01,dimensão02])

ou

arrayAntes is array of 1 by 4 STRING
Dimension(arrayAntes,1,2)

Isso por que uma Matriz Multidimensional precisa ser iniciada, sem dar a dimensao dela não funciona

Boller

28 02 2024

item limit

I have a customer who is reaching the 65,000 item limit and was wondering if an array counted as one item or that if each element in the array counted towards the total. Like MyArray ["john","mary","frank"] is that one item towards the limit or three?

DECKFURNITURE

29 03 2019

Última modificación: 06/04/2024

Señalar un error o enviar una sugerencia | Ayuda local