1. Describe a user profile. This user profile must be created in the Microsoft application for email management (MS Exchange for example).
2. From the WINDEV application (or from the WEBDEV website), connect to the application for email management (MS Exchange client for example) with EmailStartSession.
3. Send and read the messages.
4. Close the session to the application for email management (MS Exchange client for example) with EmailCloseSession.

Step 1: Creating a user profile

• the SMTP protocol used,
• the POP3 protocol used,
• the different communication services used. To use the "email" functions of WLanguage, the user profile must use the Microsoft Exchange Server.

1. Open the control panel.
2. Double-click the "Email" option.
3. Click the "Display the profiles" button.
4. In the window named "Choosing a profile", click the "Add" button.
5. Give a name to the profile. This name will be used in the WINDEV programs.
6. Select "Add a new email account".
7. Select the "Microsoft Exchange Server" service.
8. Enter the name of Microsoft Exchange server.

Step 2: Starting an email session

FUNCTION StartSession(Profile)
// Start the session
SessionNum is int
SessionNum = EmailStartSession(Profile)
IF SessionNum = 0 THEN
	Error("The session could not be opened. Error: " + Email.Error)
END
RETURN SessionNum

Step 3: Sending emails

• EmailSendMessage: this function is used to place the message in the out-box of the application for email management (out-box of the MS Exchange client for example).
• EmailUpdate: this function synchronizes the e-mail server and the e-mail management application: new e-mails received are automatically transferred to the inbox, and e-mails in the outbox are sent.

I is int
FOR I = 1 _TO_ TableCount(TABLE_TOSEND)
	// The email is sent to a single person
	Email.NbRecipient = 1
	Email.Recipient[1] = ExtractString(TABLE_TOSEND[I], 1)
	// Subject and message
	Email.Subject = ExtractString(TABLE_TOSEND[I], 2)
	Email.Message = ExtractString(TABLE_TOSEND[I], 3)
	// No attached file
	Email.NbAttach = 0
	// Send the message to MS Exchange
	EmailSendMessage(SessionNum, False)
END
// Send the messages from MS Exchange to the email server
IF NOT EmailUpdate(SessionNum) THEN
	Error("Problem with MS Exchange. Error:" + Email.Error)
END

Step 3 bis: Reading emails

• the EmailUpdate function: this function synchronizes the email server and the email management software used: new emails received are automatically transferred to the inbox, and emails in the outbox are sent.
• email reading functions (EmailReadFirst, EmailReadNext, etc.): these functions initialize the WLanguage email structure with the characteristics of the email currently being read (email author, subject, etc.).

// Receives the pending messages found on the email server
IF NOT EmailUpdate(SessionNum) THEN
	Error("Problem with MS Exchange. Error: " + Email.Error)
END

// Read the first unread message
IF NOT EmailReadFirst(SessionNum, "NOT READ") THEN
	Error("Error while reading the first message")
END

// Loop through unread messages and display them in a Table control populated programmatically
TableDeleteAll(TABLE_Messages)
WHILE NOT Email.Out
	// The reception date, the address of the sender and the message
	// are assigned to the table
	TableAdd("TABLE_Messages", Email.ReceiveDate + TAB +...
	Email.SenderAddress + TAB + Email.Message)

	// Delete the message
	IF NOT EmailDeleteMessage(SessionNum) THEN
		Error("Error during the deletion. The message was not deleted")
	END
	// Read the next unread message
	IF NOT EmailReadNext(SessionNum, "NOT READ") THEN
		Error("Error while reading the next message")
	END
END

Step 4: Ending the email session

PRODEDURE CloseSession(SessionNum)
// Close the session
EmailCloseSession(SessionNum)