sListeDesErreurs is string
// Vérification stricte de la structure de fichiers
HCheckStructure("*", hIdentical)
// Pour tous les fichiers
FOR EACH STRING sNomUnFichier OF HListFile() SEPARATED BY CR
	WHEN EXCEPTION IN 
		// Ouverture ou création du fichier de données
		HCreationIfNotFound(sNomUnFichier)
	DO
		// Problème
		// Il y a une différence de structure ?
		IF HError(hErrCurrent) = 70016 THEN 
			// Erreur 70016: LE FICHIER NE CORRESPOND PAS A SA DESCRIPTION
			ToastDisplay("Mise à jour de la structure du fichier <" + ...
				sNomUnFichier + "> en cours...", toastShort, vaMiddle, haCenter)
			// On met à jour la structure du fichier
			IF NOT HModifyStructure(sNomUnFichier) THEN
				// Echec de la mise à jour de la structure du fichier
				sListeDesErreurs += [CR] + ...
					"- Erreur de modification de structure pour le fichier <" + ...
					sNomUnFichier + "> : " + HErrorInfo()
			END
		ELSE
			// Autres erreurs qu'une différence de structure
			sListeDesErreurs += [CR] + "- Erreur d'accès au fichier <" + ...
				sNomUnFichier + "> : " + HErrorInfo()
		END
	END
END

// Vérification compatible de la structure de fichier
// Ainsi les modifications "les plus courantes" permettent 
// quand même l'utilisation de l'application (voir HVérifieStructure)
HCheckStructure("*", hCompatible)

// Il y a eu des erreurs ?
IF sListeDesErreurs <> "" THEN
	// Message afin de prévenir
	IF NOT YesNo("Des erreurs sont apparus lors de l'ouverture des fichiers : " + CR + ...
			sListeDesErreurs + CR +...
			"Continuer quand même l'application ?") THEN
			EndProgram()
	END
END